{***************************************************************}
{                                                               }
{  This line describes the purpose of the unit                  }
{                                                               }
{  Copyright (c) 2001 godrm@netsgo.com                          }
{                                                               }
{     All rights reserved.                                      }
{                                                               }
{***************************************************************}

1.3 컨디션 설정

오브젝트 파스칼 컴파일러 지시자에 사용되는 것과 마찬가지로 { } 로 컨티션 설정을 한다.

  if ... then
  begin
    {$IFDEF VER90}
      raise Exception.CreateRes(SError);
    {$ELSE}
      raise Exception.Create(SError);
    {$ENDIF VER90}
  end;

1.4 빈공간

한줄 띄우기(Blank Lines)는 저작권 주석이나, 패키지 선언, 클래스 선언, 메소드 선언들 사이에 한다.

다음의 경우에는 빈공간을 주지 않는다.

(1) 메소드 이름과 여는 괄호 사이

(2) .(점) 연산자 앞뒤

(3) 단항연사자와 연산값 사이

(4) 형변환을 위한 형과 변수

(5) 여는 소괄호 '(' 다음과 닫는 소괄호 ')' 앞

단, ()안에서 함수가 들어갈 경우나 강조할 경우는 띄어써도 무방하다.

(6) 여는 대괄호 '[' 다음과 닫는 소괄호 ']' 앞

(7) 세미콜론 앞

  //CORRECT
  function TMyClass.MyFunc(var Value: Integer);
  MyPointer := @MyRecord;
  MyClass := TMyClass(MyPointer);
  MyInteger := MyIntegerArray[5];
  ShowMessage( IntToStr(MyInteger) );

  //INCORRECT
  function TMyClass.MyFunc( var Value: Integer ) ;
  MyPointer := @ MyRecord;
  MyClass := TMyClass ( MyPointer ) ;
  MyInteger := MyIntegerArray [ 5 ] ;

1.5 기타( 토큰 분리자, 연산자, begin-end )

대부분의 토큰 분리자나 연산자는 붙여쓰는 것을 원칙으로 한다.

단, 사칙연산( +, -, *, /, div, mod )와 부등호( >, <, = ) 그리고 대입연산자( := )는 띄어쓴다.

begin-end 는 같은 레벨에 맞춰 쓴다.

단, if-else 문과 사용되는 경우에는 예외를 둔다. (3.5장 (1)if문 참조)

  for I := 0 to 10 do begin // Incorrect, begin on same line as for
  for I := 0 to 10 do       // Correct, begin appears on a separate line
  begin

블럭문내의 마지막 명령줄의 생력가능한 세미콜론도 찍어주는 것을 원칙으로 한다.

begin
  MyStatement;
  MyNextStatement;
  MyLastStatement;   // semicolon optional
end;

2. 파일이름

파일이름에는 InfixCaps 혹은 Camel Caps 방식인 단어 첫 알파벳만 대문자를 쓰는 방식으로 한다.

단, 확장자는 소문자로 한다.

2.1 프로젝트 파일

프로젝트명은 될 수 있으면 프로젝트의 내용을 설명하도록 만들며,

정해진 프로젝트 코드명이 있을 경우에는 코드명을 사용한다.

2.2 폼 파일

폼 파일명은 기능별 혹은 구성별로 붙일 수 있는 기능성이름과 Form이라는 postfix를 사용한다.

( 실제로 폼의 .dfm 파일은 유닛 파일명을 저장할 때, 같은 이름으로 그대로 저장된다. )

유의사항: 폼 파일명은 디자인한 폼 클래스의 인스턴스명이 아니다.

폼의 인스턴스는 TForm 클래스명인 Form이라는 prefix를 붙인다. (3.8 인스턴스명 참조)

폼 설명	폼 파일명
About Form	AboutForm.dfm
Main Form	MainForm.dfm

2.3 유닛 파일

델파이 폼의 유닛 이름은 자동적으로 폼 파일과 같은 이름을 사용한다. (2.2 폼 파일이름 참조),

반면에 일반 유닛일 경우에는 Unit이라는 postfix를 사용한다.

단, C/C++의 헤더파일을 변환하는 경우에는 확장자를 제외한 파일명을 그대로 사용한다.

유닛 설명	유닛 파일명
About Form Unit	AboutForm.pas
Service Unit	ServiceUnit.pas
Windows.c	Windows.pas

2.4 데이터모듈 파일

데이터 모듈의 파일명에는 DM이라는 postfix를 사용한다.

DM 설명	DM 파일명
Client Data Module	ClientDM.dfm
Customer Data Module	CustomerDM.dfm

2.5 패키지 파일

패키지 파일명에는 구분할 수 있는 prefix에

디자인타임패키기와 런타임패키지를 구분할 수 있는 infix와

지원하는 델파이버전을 나타내기 위한 D4, D5, D6와 같은 postfix로 구성한다.

"iiilibvv.pkg" - design package

"iiistdvv.pkg" - runtime package

3. 오브젝트파스칼

3.1 예약어

모든 오브젝트파스칼 예약어는 소문자로 쓰도록 한다.

3.2 함수명

함수명은 동사(+목적어) 형태로 사용하며, 값을 가져오는 경우 Get, 값을 설정하는 경우 Set을 쓴다.

InfixCaps 방식을 사용한다.

  procedure ThisIsMuchMoreReadableRoutineName;

  procedure FormatHardDrive;

  procedure SetUserName;

  function GetUserName: string;

3.3 변수명

변수명은 명사 형태로 사용하며, InfixCaps 방식을 사용한다.

변수선언을 할 때는 같은 형끼리는 복수선언하며, 다른 형끼리는 단수선언만 한다.

델파이에서는 WIN32 형식인 헝가리언 표기법을 권장하지 않는다.

하지만, WIN32 API를 사용할 경우나, VisualStudio와 같은 다른 툴과의 연동을 위해서는 사용해도 무방하다.

  var
    nLoop, MyNumber: Integer; // Correct
    lpstrMyString: String; // Incorrect

클래스의 멤버 변수일 경우, F(Field) prefix를 주로 사용한다.

필요에 따라서 P(Pointer-포인터형변수), G(Global-전역변수), L(Local-지역변수), X(temp-임시변수), A(argument-함수파라미터)등의 prefix를 붙일 수 있다.

3.4 데이터타입

내부 테이터형은 소문자로 표기하며, WIN32 API 데이터형은 대문자로 표기한다.

  var
    MyString: string;  // reserved word
    WindowHandle: HWND; // Win32 API type
    I: Integer;         // type identifier introduced in System unit

열거형은 선언할 때는 T(Type) prefix를 붙이며, 열거형 내부 목록에는 열거형에 대한 구분자(혹은 약자)를 2-3글자 prefix로 붙인다.

  TSongType = (stRock, stClassical, stCountry);

배열형의 경우에는 T prefix, Array postfix를 붙이며,

또한 데이터의 포인터형은 P(Pointer) prefix를 덧붙인다.

  type
    PCycleArray = ^TCycleArray;
    TCycleArray = array[1..100] of Integer;

레코드의 경우에도 T prefix를 사용하며, 레코드 내부 변수에는 붙이지 않는다.

  type
    PEmployee = ^TEmployee;
    TEmployee = record
      Name: string;
      Rate: Double;
    end;

3.5 구문

(1) if문

if문은 적어도 두 줄로 내려쓴다.

다만 수행문이 짧으면 한 줄로 써도 무방하다.

  // CORRECT
  if A < B then DoSomething; 
  
  // CORRECT
  if A < B then 
    DoSomething;

if-else문의 경우 소스의 논리 구조를 표현하는 수단이다.

각 논리 블록간의 관계가 명확하게 구분된다면, 자유로운 레벨간의 들여쓰기와 begin-end 표시가 허용된다.

그리고 특히 if문이 반복되서 길 게 사용될 경우 begin-end를 표시하여 범위를 명확하게 한다.

가능하면 if-else를 반복해서 사용하지 않도록 하며, 될 수 있으면 case문으로 구성한다.

  // INCORRECT
  if A < B then     
  if C < B then 
    DoSomething
  else if D < B then 
    DoSomething;
  // CORRECT
  if A < B then     
  begin 
    if C < B then 
      DoSomething;
  end
  else if D < B then 
    DoSomething;

if문안에 if문의 구조가 5단계이상 들어가지 않도록 코드를 간결화한다.

여러 조건들은 나열할 때는 왼쪽부터 빈도가 높고, 가능성이 높은 것을 선택한다.

  if Condition1 and Condition2 and Condition3 then

(2) case문

case문은 순서가 있는 데이터형에만 사용할 수 있다.

case-else문도 if-else와 같이 논리 블록간이 명확하게 구분되는 범위에서 들여쓰기가 허용된다.

if문과 마찬가지로 중요도와 빈도가 높은 것이 윗쪽에 있도록 한다.

각 case마다 4-5줄을 넘어가지 않도록 하며, 길어질 경우 따로 함수를 작성하도록 한다.

  // CORRECT
  case Control.Align of
    alLeft, alNone: NewRange := Max(NewRange, Position);
    alRight: Inc(AlignMargin, Control.Width);
  end;
 
  // CORRECT
  case x of
    csStart:
      begin
        j := UpdateValue;
      end;
    csBegin: x := j;
    csTimeOut:
      begin
        j := x;
        x := UpdateValue;
      end;
   end;
      
  // CORRECT
  case ScrollCode of
    SB_LINEUP, SB_LINEDOWN:
    begin
      Incr := FIncrement div FLineDiv;
      FinalIncr := FIncrement mod FLineDiv;
      Count := FLineDiv;
    end;
    SB_PAGEUP, SB_PAGEDOWN:
    begin
      Incr := FPageIncrement;
      FinalIncr := Incr mod FPageDiv;
      Incr := Incr div FPageDiv;
      Count := FPageDiv;
    end;
    else
      Count := 0;
      Incr := 0;
      FinalIncr := 0;
  end;
  
  // CORRECT (볼랜드 스타일)
  case ScrollCode of
    SB_LINEUP, SB_LINEDOWN:
      begin
        Incr := FIncrement div FLineDiv;
        FinalIncr := FIncrement mod FLineDiv;
        Count := FLineDiv;
      end;
    SB_PAGEUP, SB_PAGEDOWN:
      begin
        Incr := FPageIncrement;
        FinalIncr := Incr mod FPageDiv;
        Incr := Incr div FPageDiv;
        Count := FPageDiv;
      end;
  else
    Count := 0;
    Incr := 0;
    FinalIncr := 0;
  end;

(3) while문 (repeat문)

while문에서는 가능하면 루프중에 빠지지않고, loop조건으로만 종료되도록 구성한다.

 // INCORRECT
  while x < j  do begin
    DoSomething; 
    DoSomethingElse;
  end;
  // CORRECT
  while x < j do 
  begin
    DoSomething; 
    DoSomethingElse;
  end;
  
  // CORRECT
  repeat
    x := j;
    j := UpdateValue;
  until j > 25;

(4) for문

만약 1씩 증가가 아닌 경우라면, while문을 이용해서 마지막값부터 거꾸로 루프를 돌도록 한다.

  // INCORRECT
  for i := 0 to 10 do begin
    DoSomething; 
    DoSomethingElse;
  end;
  
  // CORRECT
  for i := 0 to 10 do 
  begin
    DoSomething; 
    DoSomethingElse;
  end;
  
  // CORRECT
  i := AList.Count-1;
  while i => 0 do
    i := i - 2;

(5) with문

with문을 사용할 경우에는 복수객체나 구조체를 참조하지 않도록 주의하며,

같은 이름의 다른 객체의 프로퍼티나 메소드를 참조하지 않는지 확인해야 한다.

  with Record1, Record2 do

3.6 에러처리구문

에러처리 (Exception Handling)는 에러 복구와 리소스 보호의 역할을 한다.

(1) try..finally

되도록 각 동적할당마다 try..finally 구문을 사용하여 예외사항에 대비한다.

다음의 예제는 동적할당된 클래스를 참조할 때, 예외가 발생할 수 있는 숨겨진 버그가 있다.

  SomeClass1 := TSomeClass.Create
  SomeClass2 := TSomeClass.Create;
  try
    { do some code }
  finally
    SomeClass1.Free;
    SomeClass2.Free;
  end;

다음의 예제는 숨겨진 버그를 없애는 올바른 방법이다.

  SomeClass1 := TSomeClass.Create
  try
    SomeClass2 := TSomeClass.Create;
    try
      { do some code }
    finally
      SomeClass2.Free;
    end;
  finally
    SomeClass1.Free;
  end;

(2) try..except

특정 예외 사항이 발생했을 때의 행동을 위해 사용한다.

  // Correct
  try
    try
      EnumThreadWindows(CurrentThreadID, @Disable, 0);
      Result := TaskWindowList;
    except
      EnableTaskWindows(TaskWindowList);
      raise;
    end;
  finally
    TaskWindowList := SaveWindowList;
    TaskActiveWindow := SaveActiveWindow;
  end;

(3) try..except..else

혹시 처리되지 않는 에러을 위해서는 else 구문을 사용한다.

3.7 클래스명

클래스의 Access Level은 Private, Protected, Public, Published 순으로 낮으며,

데이터는 될 수 있으면 Public 레벨을 사용하지 않고, Private 레벨을 사용하면서 Access Method를 활용한다.

클래스명은 T(Type) prefix를 붙이고 기능/목적상의 이름을 붙인다.

3.8 인스턴스명

클래스의 인스턴스명은 클래스명을 앞에 붙이고, 기능/목적상의 이름을 붙인다.

예) FormMain, FormAbout, ButtonShowList , ButtonLoadImage

단, 유사한 기능의 클래스는 같은 클래스로 묶어도 무방하다

예) TButton과 TSpeedButton의 예

강조를 위해서나, 뒤에 붙는 이름과 특별히 구분이 필요할 경우에는 '_' 를 넣어도 된다.

예) FormMain, Form_About, Button_SaveToFile , Button_LoadFromFile

3.9 인터페이스

클래스와 같은 방식으로 선언하도록 한다.

자료정리 : 김정(고드름)

출처 : http://www.delmadang.com/community/bbs_view.asp?bbsNo=23&bbsCat=50&indx=399176

이 글은 스프링노트에서 작성되었습니다.

'Document' 카테고리의 다른 글

[매뉴얼] Intergraph SPLM Client라이센스 설정법 - SmartPlant Instrument(SPI, INTools) 기준 (0)	2012.06.27
대한민국의 전화번호 체계 (0)	2011.05.16
헝가리안 표기법 (0)	2008.07.16

'Document' 카테고리의 다른 글

티스토리툴바